Windows - RDP 포트 변경 및 원격 데스크톱 설정 방법

원격 데스크톱(RDP)을 사용할 때 포트를 변경하거나, 원격 데스크톱을 처음 설정하는 경우 직접 설정하는 방법을 소개합니다.

이 가이드는 초보자도 쉽게 따라 할 수 있도록 단계별로 설명하며, 필요한 설정 화면도 함께 안내합니다.

---

1. 원격 데스크톱(RDP) 포트란?

원격 데스크톱은 기본적으로 3389번 포트를 사용하여 연결을 처리합니다.

일반적으로 기본 포트를 사용하는 경우 보안 위협에 노출될 가능성이 높아 다른 번호로 변경하는 것이 보안에 유리합니다.

 

---

2. RDP 포트를 변경하는 방법

(1) 배치 파일로 포트 변경하기

배치 파일을 사용하면 RDP 포트를 쉽게 변경할 수 있습니다.

1. 배치 파일 작성
   • 메모장을 열고 아래 코드를 복사합니다.
   • 파일 이름을 포트변경.bat로 저장합니다. (다른 이름 상관없음)
   • 저장할 때 파일 형식을 "모든 파일"로 설정해야 합니다.
   • 인코딩은 "ANSI"로 설정해야 합니다.
     

     @echo off
     
     bcdedit > nul || (echo 관리자 권한으로 실행하세요. & pause & exit)
     
     :MENU
     cls
     echo =====================================
     echo 원격 데스크톱 포트 관리 스크립트
     echo =====================================
     echo 1. 원격 데스크톱 포트 변경
     echo 2. 설정한 원격 데스크톱 포트 삭제
     echo 3. 설정한 원격 데스크톱 목록 확인
     echo 4. 종료
     echo =====================================
     set /p select=메뉴 선택 (1,2,3,4): 
     
     if "%select%"=="1" (
         goto CHANGE_PORT
     ) else if "%select%"=="2" (
         goto DELETE_PORT
     ) else if "%select%"=="3" (
         goto VIEW_PORTS
     ) else if "%select%"=="4" (
         echo 프로그램을 종료합니다.
         exit
     ) else (
         echo 유효하지 않은 입력입니다. 다시 입력해주세요.
         pause
         goto MENU
     )
     
     :CHANGE_PORT
     cls
     echo =====================================
     echo 원격 데스크톱 포트 변경
     echo =====================================
     set /p port=변경할 포트 번호 입력 (0~65535): 
     
     if "%port%"=="" goto INVALID_PORT
     if %port% LSS 1 goto INVALID_PORT
     if %port% GTR 65535 goto INVALID_PORT
     
     echo 포트를 %port%로 변경합니다...
     reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 0 /f
     reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v PortNumber /t REG_DWORD /d %port% /f
     netsh advfirewall firewall add rule name="원격 데스크톱 %port%" dir=in action=allow protocol=tcp localport=%port%
     net stop TermService
     net start TermService
     echo 원격 데스크톱 포트가 %port%로 변경되었습니다.
     echo 시스템을 재부팅하면 변경 사항이 적용됩니다.
     pause
     goto MENU
     
     :DELETE_PORT
     cls
     echo =====================================
     echo 설정한 원격 데스크톱 포트 삭제
     echo =====================================
     set /p del_port=삭제할 포트 번호 입력: 
     
     if "%del_port%"=="" goto INVALID_PORT
     
     echo 포트 %del_port%의 방화벽 규칙을 삭제합니다...
     netsh advfirewall firewall delete rule name="원격 데스크톱 %del_port%" dir=in protocol=tcp localport=%del_port%
     echo 포트 %del_port%에 대한 규칙이 삭제되었습니다.
     pause
     goto MENU
     
     :VIEW_PORTS
     cls
     echo =====================================
     echo 설정된 원격 데스크톱 포트 목록
     echo =====================================
     netsh advfirewall firewall show rule name=all dir=in | findstr /C:"원격 데스크톱"
     pause
     goto MENU
     
     :INVALID_PORT
     echo 유효하지 않은 포트 번호입니다. 0~65535 사이의 숫자를 입력하세요.
     pause
     goto MENU

     
     

     

     
     
     
2. 배치 파일 실행
   • 작성한 배치 파일을 관리자 권한으로 실행합니다.
   • 메뉴에서 "1번"을 선택한 뒤, 사용할 포트 번호를 입력합니다.
3. 변경 확인
   • 변경한 포트로 원격 데스크톱이 정상적으로 작동하는지 확인하세요.

---

(2) 레지스트리 편집기로 포트 변경하기

1. 레지스트리 편집기 열기
   • Windows 검색창에 regedit를 입력하고 실행합니다.
     

     

2. RDP 포트 경로로 이동
   • HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp
3. PortNumber 수정
   • PortNumber 항목을 더블 클릭합니다.
   • 기본값은 3389로 설정되어 있을 겁니다.
   • 10진수를 선택한 뒤, 변경하려는 포트 번호를 입력하고 저장합니다.
     

     

4. 변경 사항 저장 후 재부팅
   • 레지스트리 변경 후 시스템을 재부팅하여 설정이 적용되도록 합니다.

---

3. 원격 데스크톱을 켜는 방법

RDP 포트 변경 외에도 원격 데스크톱을 활성화하는 과정도 필요합니다. 

1. 시스템 속성 열기 (Win 10 기준)
   • Windows 검색창에 "시스템"을 입력하거나 제어판 - 시스템을 엽니다.
   • 왼쪽 메뉴에서 "원격 데스크톱"을 클릭합니다.
     

     

2. 원격 데스크톱 활성화
   • 원격 데스크톱 활성화를 켭니다.
   • 고급 설정이 필요한 경우 "고급 설정" 을 클릭 후 설정하시면 됩니다.
3. 방화벽 규칙 추가
   • 제어판에서 Windows Defender 방화벽 > "고급 설정"으로 이동합니다.
   • 새 규칙을 생성하여 원격 데스크톱 포트를 허용합니다.

 

---

자주 묻는 질문(FAQ)

Q1. RDP 포트를 꼭 변경해야 하나요?

기본 포트(3389)는 해커들의 공격 대상이 되기 쉽습니다.

포트를 변경하면 비인가 접근 시도를 줄이고 보안을 강화할 수 있습니다.

Q2. 변경한 포트를 사용하려면 어떻게 연결하나요?

RDP 클라이언트에서 IP주소:포트번호 형식으로 입력해야 합니다. 예: 172.16.30.100:1256

Q3. 연결이 되지 않으면 어떻게 하나요?

방화벽 설정을 확인하거나, 포트가 제대로 열려 있는지 확인하세요. 변경 후에는 반드시 재부팅해야 설정이 적용됩니다.